

 # INTERFACE TO EP4IR LEXICON
 # This is the place to link to other lexica
 # or to link to lexica with a different tagset.

 # ------------------------------------------------ADJ
 LEX_ADJE(GRAD,PREP): LADJE(GRAD,PREP) /"A:", LADJE.

 LADJE(GRAD,PREP):
   ADJE(GRAD,PREP);
   NUM(ord)!
    # EX do not attempt to break the seventh seal 
   robust ADJE(GRAD), {PREP::none} /
          "R:", robust ADJE.

 robust ADJE(GRAD):
    hyphenated form .
 # EX that was my never-do-well nephew 
 # EX he was not a cabbage-eating man 
 # EX she wore a moth-eaten mink coat 

 LEX_ADJE_TO(GRAD):
     ADJE_TO(GRAD) /
          "A:", ADJE_TO.

 hyphenated form:
        $PENALTY(2), $SKIP("[a-zA-Z0-9]+-[-a-zA-Z0-9]+").
	
 # ------------------------------------------------ADVB

 LEX_ADVB: LADVB / "X:", LADVB.
  
 LADVB:
    ADVB!
    $PENALTY(3), $SKIP(".*ly").
    
 
 # ------------------------------------------------AUXV

 LEX_AUXV(NUMB,PERS):
    AUXV(NUMB,PERS).
    
 # ------------------------------------------------ART
 
 LEX_ART(NUMB):
    ART(NUMB).
 
 # ------------------------------------------------NOUN

 LEX_NOUN(NUMB): LNOUN(NUMB)/ "N:", LNOUN.

 LNOUN(NUMB):
    NOUNC(NUMB);
    NOUNT(TRAD, NUMB) / 
          TRAD;
    NOUN(NUMB)!
    $PENALTY, TNOUN, {NUMB :: sing};
    $PENALTY(2), MONTH, {NUMB :: sing};
     # EX April is the cruellest month 
    $PENALTY(2), company /
          "M:", company!
    $PENALTY(3), number /
          "Q:", number;
    $PENALTY(3), dimension /
          "Q:", dimension;          
    $PENALTY(3), name /
          "M:", name.
          
 number:
    NUM(card), opt number ;
    numeral, [scaldim] ;
	scaldim, numeral /
        numeral, scaldim;
	$SKIP("[$£]-"), numeral /
        numeral, $SKIP.
  
 opt number:
    number; 
		.
 
 scaldim:
    "percent";
    "%" / "percent";
    "dollar";
    "dollars" / "dollar";
    "$"/ "dollar";
		"£" / "pound".
		
 numeral:
    $SKIP("[a-z][0-9]+")!
  # EX look at paragraph b1
    $SKIP("[0-9]+ +[0-9]+/[0-9]+")!
  # EX GM stocks rose 2 1/2 points 
    $SKIP("[0-9][0-9+-/\.,*]*") / "\"", $SKIP, "\""!
  # EX 4,403,197
    $SKIP("[+-\.][0-9]+").
    
 dimension:
 		DIMENSION.

 company:
    name, [company ext].

 company ext:
    "inc[\.]?";
    "co[\.?]";
    "& co[\.?]";
    "corp[\.?]";
    "ltd[\.?]".

 name:
    element;
    element, name;
    element, "&", name;
	element, "\-", name.

 element:
    PNAME!
    letter, letter, $MATCH("[A-Z][-A-Za-z]+")!
    letter, $MATCH("[A-Z][-A-Za-z]+")!
    $SKIP("[A-Z][-A-Za-z]+").
 # The letters (with dot) are highly indicative of a name (MATCH)
 # Just a word starting with a capital letter is not, therefore SKIP

 letter: $MATCH("[A-Z]\.").


 # ------------------------------------------------PARTICLE

 LEX_PARTICLE(PART):
    PARTICLE(PART).
 
 # ------------------------------------------------VERB

 LEX_VERBI(PREP, TRAN, XPART):
    VERBI(PREP,TRAN, XPART) / "V:", VERBI, XPART.
 LEX_VERBI(PREP, TRAN): 
    VERBI(PREP, TRAN) / "V:", VERBI.

 LEX_VERBS(PREP, TRAN, XPART):
    VERBS(PREP, TRAN, XPART) / "V:", VERBS, XPART.
 LEX_VERBS(PREP, TRAN):
    VERBS(PREP, TRAN) / "V:", VERBS.

 LEX_VERBV(PREP, TRAN, XPART):
    VERBV(PREP, TRAN, XPART) / "V:", VERBV, XPART.
 LEX_VERBV(PREP, TRAN):
    VERBV(PREP, TRAN) / "V:", VERBV.

 LEX_VERBG(PREP, TRAN, XPART):
    VERBG(PREP, TRAN, XPART) / "V:", VERBG, XPART.
 LEX_VERBG(PREP, TRAN):
    VERBG(PREP, TRAN) / "V:", VERBG.

 LEX_VERBP(PREP, TRAN, XPART):
    VERBP(PREP, TRAN, XPART) / "V:", VERBP, XPART.
 LEX_VERBP(PREP, TRAN):
    VERBP(PREP, TRAN) / "V:", VERBP.
    
 # ------------------------------------------------COPULA

 LEX_COPI:
   COPI.
 LEX_COPS:
   COPS.
 LEX_COPP:
   COPP.
 LEX_COPV:
   COPV.
 LEX_COPG:
   COPG.

 # ------------------------------------------------DETERMINER

LEX_DET(NUMB): DET(NUMB).
LEX_PREDET(NUMB): PREDET(NUMB).

 # ------------------------------------------------PREPOSITION

 LEX_PREPOS(PREP):
    PREPOS(PREP).
 LEX_PREPOS:
    PREPOS.
 
 # ------------------------------------------------PRONOMINA

 LEX_POSSPRON:
    POSSPRON.
    
 LEX_PERSPRON(NUMB, PERS, CASE):
    PERSPRON(NUMB, PERS, CASE).

 LEX_REFLPRON(NUMB,PERS):
    REFLPRON(NUMB,PERS).
    
 LEX_GENPRON:
    GENPRON.
    
 LEX_RELPRON(CASE):
    RELPRON(CASE).
 
 LEX_QPRON(CASE):
    QPRON(CASE).
 
 # ------------------------------------------------TO BE/HAVE

 LEX_TOBE(NUMB, PERS):
    TOBE(NUMB, PERS).
 LEX_TOBE(TENS):
    TOBE(TENS).

 LEX_TOHAVE(NUMB, PERS):
    TOHAVE(NUMB, PERS).
 LEX_TOHAVE(TENS):
    TOHAVE(TENS).
 
 # ------------------------------------------------NUM

 LEX_NUM(TYPE):
    NUM(TYPE).
 
 # ------------------------------------------------CON

 LEX_CON(LEVEL):
    CON(LEVEL).

Wmore: "more".
Wthan: "than".
Wof: "of".
Wand: "and".
Wto: "to".
Wthat: "that".
Wnor: "nor".

Wquoteclose: "''"; "\"".
Wquoteopen: "``"; "\"".
Waccent s: "-'s".
Wcomma: ",-" / ; "," / .

